Growth of GV/DT/PT invariants

Following “Black holes and large order geometry” [arXiv:0704.2440]

Check eqs 3.2, 3.20 for the coeffs b0, b1, p0

ClearAll[SS,m,Q,c2,kappa,d,m];
SS=2Pi Sqrt[Q^3-m^2]+Pi c2/8(6/kappa)^(1/3)(1/Q+m^2/(3Q^4)) Sqrt[Q^3-m^2];
Simplify[Series[(SS/.{Q->(2/9/kappa)^(1/3)d})/d^(3/2),{d,Infinity,3}],{d>0,kappa>0}]
Simplify[Series[(SS-(SS/.m->0)/.{Q->(2/9/kappa)^(1/3)d})d^(3/2)/m^2,{d,Infinity,0}],{d>0,kappa>0}]

Import GV/DT/PT Tables

ClearAll[pmax,lmax,h1,GVTab,PTTabnew,DTTabnew,PTTabGv,DTTabGv,h1fun,h1int,h1ser];
SetDirectory[NotebookDirectory[]];
(* choose your favorite CICY *)
<<X5.m
{CY,chi,kappa,c2}

(* maximal genus and degree in the table of GV invariants *)
gmaxGV=Length[GVTab]-1;
QmaxGV=Length[Transpose[GVTab]];
(* the maximal degree which gives rise to the genus satisfying the Castelnuovo bound *)
QmaxGVg=Floor[Q/. Solve[((Q^2)/(2 kappa))+(Q/2)+1==gmaxGV,Q][[2]]];
(* Castelnovo bound on the genus of GV invariants *)
gMax[Q_]:=Floor[((Q^2)/(2 kappa))+(Q/2)+1];
(* Castelnuovo bound on the D0-charge for PT invariants *)
MMin[Q_]:=Ceiling[-((Q^2)/(2kappa))-(Q/2)];

{gmaxGV,QmaxGVg}

Asymptotics of BH index, m=0

b0=4Pi/3/Sqrt[2kappa];
b1=Pi c2/4/Sqrt[2kappa];
BHTab=With[{m=0},Table[Sum[Binomial[2g+2,m+g+1]GVTab[[g+1,d]],{g,0,gMax[d]}],{d,QmaxGVg}]];
fTab=Table[N[Log[BHTab[[d]]]/d^(3/2)],{d,QmaxGVg}];
fTab1=Table[d(fTab[[d]]-b0),{d,QmaxGVg}];
Richardsonf[n_]:=Table[Sum[fTab[[d+k]](d+k)^n(-1)^(k+n)/k!/(n-k)!,{k,0,n}],{d,QmaxGVg-n}]/b0;
Richardsonf1[n_]:=Table[Sum[fTab1[[d+k]](d+k)^n(-1)^(k+n)/k!/(n-k)!,{k,0,n}],{d,QmaxGVg-n}]/b1;

(* leading coefficient *)
Richardsonf[4]

ListPlot[{fTab,Richardsonf[1],Richardsonf[2],Richardsonf[3]}]

(* plot last term as a function of order of Richardson transform *)
ListPlot[Table[Last[Richardsonf[n]],{n,1,QmaxGVg-1}]]

(* subleading coefficient *)
Richardsonf1[4]

ListPlot[{fTab1,Richardsonf1[1],Richardsonf1[2],Richardsonf1[3]}]

(* plot last term as a function of order of Richardson transform *)ListPlot[Table[Last[Richardsonf1[n]],{n,1,QmaxGVg-1}]]

b1 Last[Richardsonf1[3]]

Asymptotics of BH index, m>0

BHTab1=With[{m=1},Table[Sum[Binomial[2g+2,m+g+1]GVTab[[g+1,d]],{g,0,gMax[d]}],{d,QmaxGVg}]];
fTabm=Table[N[Log[BHTab[[d]]/BHTab1[[d]]]d^(3/2)],{d,QmaxGVg}];
p0=3Pi Sqrt[kappa/2];
Richardsonfm[n_]:=Table[Sum[fTabm[[d+k]](d+k)^n(-1)^(k+n)/k!/(n-k)!,{k,0,n}],{d,QmaxGVg-n}]/p0;

Richardsonfm[1]

(* This plot doesn't seem to converge to 1 ! *) 
ListPlot[{Richardsonfm[1],Richardsonfm[2],Richardsonfm[3]}]

(* plot last term as a function of order of Richardson transform *)ListPlot[Table[Last[Richardsonfm[n]],{n,1,5}]]

Asymptotics of DT invariants, m=0

(* Log[PT[mu,0]] vs mu *)
DTTab0=Table[DTTabnew[[mu+1,-MMin[mu]+2]],{mu,1,QmaxGVg}];
fTab=Table[N[Log[DTTab0[[d]]]],{d,3,QmaxGVg}];

(* this plot looks pretty linear !*)
ListPlot[fTab]

(* Log[Log[DT[mu,0]]]/Log[mu] vs mu *)fTabDT=Table[N[Log[Log[DTTab0[[d]]]]/Log[d]],{d,3,QmaxGVg}];
RichardsonfDT[n_]:=Table[Sum[fTabDT[[d+k]](d+k)^n(-1)^(k+n)/k!/(n-k)!,{k,0,n}],{d,Length[fTabDT]-n}]
ListPlot[{fTabDT,RichardsonfDT[1],RichardsonfDT[2]}]

Asymptotics of PT invariants, m=0

(* Log[PT[mu,0]] vs mu *)
PTTab0=Table[PTTabnew[[mu+1,-MMin[mu]+2]],{mu,1,QmaxGVg}];
fTab=Table[N[Log[PTTab0[[d]]]],{d,3,QmaxGVg}]

ListPlot[fTab]

(* Log[Log[PT[mu,0]]]/Log[mu] vs mu *)
fTab=Table[N[Log[Log[PTTab0[[d]]]]/Log[d]],{d,3,QmaxGVg}];
ListPlot[fTab]